如图 21‑1所示，某人向银行存款10000元，存款年利率为3%，存款期为3年，3年后此人可向银行提取多少钱（单利计息）？

在B5单元格输入以下简单公式，即可计算3年后的本利和。

=10000*(1+0.03*3)

图 21-1 计算单利下的未来值

如图 21‑2所示，假如银行存款利率为3%，某人为了3年后取得10000元，现需要向存款存款多少钱（单利计息）？

在B5单元格输入以下简单公式，可解决上述问题。

=10000/(1+0.03*3)

图 21-2 计算单利下的现值

21.2.1 FV( )函数

FV函数用于计算在固定利率及等额分期付款方式下，返回某项投资的未来值。

FV(rate,nper,pmt,[pv],[type])

参数说明：

rate：利率。

nper：期数。

pmt : 各期所支付或收取的金额

pv：现值。

type：付款类型，数字0或1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

如图 21‑3所示，假如银行存款利率为5%，某人在2016年1月1日向该银行存款100000元，存款期为3年，假设该银行为复利计息，那3年后（2019年1月1日）该用户可取出多少钱？

在B7单元格，输入以下公式，可解决上述问题。

=FV(B1,B2,0,B4,B5)

图 21-3 计算单笔存款未来值

因该用户只在期初存为100000元，即后续每年的存款额为0，此情形为单笔收支，所以FV的第三个参数（pmt）的值设置为0。此外是期初存款，所以付款类型为1。

如表 2所示，某人从2016年1月1日起开始向某银行存入现金，以2016年1月1日为期初，此时点并未存款，存款都于每年年底，存款金额每次为1000（共4笔），现需要计算此人在2020年12月31日能从银行取出多少钱？（假如该银行采复利计息，年利率为8%）

此案例为一系列等额收支，为年金形式。图 21‑4为表 2的Excel转化形式，其中B3单元格中的值表示每年存款金额，B4单元格中的值为初始存款，即存款期限以2016年1月1日为起期初点，但这一天并没有存款，所以期初的初始存款为0，B5中的0值表示存款类型为期末，即2016年12月31日存款，这一天是存款周期的期末，用0表示期末。

在B7单元格输入以下公式，可计算上述条件后的未来值。

=FV(B1,B2,B3,B4,B5)

此案例与财务管理学中求普通年金方法一致。

图 21-4 计算普通年金未来值

延续上例部分数据，如表 3所示，若该用户在2016年1月1日进行了初始存款。并且在后续4年内的每年年底存入1000元，现需要计算在2020年12月31日能从银行取出多少钱？

图 21‑5为表 3的Excel转化形式，在此提醒用户，因为在此案例中用户在2016年1月1日的这一天进行1000元存款，所以在B4单元格中的-1000为初始存款金额。期数仍为4期，每次存款额为1000，存款类型仍为期末。

在B7单元格中输入以下公式，可计算上述条件后的未来值。

=FV(B1,B2,B3,B4,B5)

此案例与财务管理学中求预付年金方法一致。

图 21-5 计算预付年金未来值

21.2.2 PV( )函数

PV函数用于计算某项投资的现值。

语法:PV(rate, nper, pmt, [fv], [type])

参数说明：

rate：利率

nper:期数

pmt：各期所支付或收取的金额

fv: 未来值

type：付款类型，数字0或1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

如图 21‑6所示，假如银行存款利率为5%，某人4年后需要资金100000元，那此人现在应向银行存入资金多少元？（假设银行为复利计息）

此案例为求某笔未来资金的现值，在B7单元格中输入以下公式，可解决上述问题。

=PV(B1,B2,B3,B4,B5)

图 21-6 计算单笔资金现值

如图 21‑7所示，某人向银行购买某理财产品，该理财产品年利率为5%，用户需每月末支出10000元，共4期，现需计算该系列支出（年金）的现值为多少?

在B7单元格中，输入以下公式，可解决上述问题。

=PV(B1,B2,B3,B4,B5)

图 21-7 计算多笔资金（年金）现值

21.2.3 PMT( )函数

PMT用于计算在固定利率下及等额分期付款方式下的每期还款额。

语法：PMT(rate, nper, pv, [fv], [type])

参数说明：

rate：贷款利率。

nper：贷款的付款总期数。

pv：现值，即贷款本金。

fv：未来值，或在最后一次付款后希望得到的现金余额。如果省略该参数，则默认值为0。

type：付款类型，数字0或1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

请用户注意，参数rate和nper所用的单位要一致。如果要以10%的年利率按月支付一笔5年期的贷款，则 rate 应为10%/12，nper 应为 5*12。如果按年支付同一笔贷款，则rate使用10%，nper使用 5。

如图 21‑8所示，某人向金融机构贷款2 400 000元，贷款期限为30年，年利率为8%，计算每月等额还款额。

在B5单元格中输入以下公式，可计算每月还款额。

=PMT(B1/12,B2*12,B3)

计算结果为17610.35元，即该借款者在未来30年内每月需向金融机构固定还款17610.35元。

图 21-8 使用PMT函数计算每月还款额

21.2.4 PPMT( )、IPMT( )函数

实际生活中，向金融机构偿还贷款的付款额由两部分组成：本金和利息。

PPMT函数用于计算固定利率下及等额分期付款方式下的每期付款额中的本金额。

IPMT函数用于计算固定利率下及等额分期付款方式下的每期付款额中的利息额。

语法：PPMT(rate, per, nper, pv, [fv], [type])

语法：IPMT(rate, per, nper, pv, [fv], [type])

参数说明：

rate：贷款利率。

per:支付的期数，1表示第一次支付。该参数必须在1~nper之间。

nper：贷款的付款总期数。

pv：现值，即贷款本金。

fv：未来值，或在最后一次付款后希望得到的现金余额。如果省略该参数，则默认值为0（零）。

type：付款类型，数字0或1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

如图 21‑9所示，某人向金融机构贷款2 400 000元，贷款期限为30年，年利率为8%，计算第1次月还款额中的本金和利息分别是多少？

在B6、B7单元格中输入以下公式，可分别计算第1个月还款额中的本金和利息额。

=PPMT(B1/12,B2,B3*12,B4)

=IPMT(B1/12,B2,B3*12,B4)

图 21-9 使用PPMT与IPMT函数计算每月还款本金和利息额

PPMT与IPMT可分离每月等额还款中本金和利息分别是多少，不同的期数的还款额中的本金和利息是不相同的，还款期数越多相应的还款本金越来越多，而相应的利息越来越少，但本金和利息总和始终为固定数，如图 21‑9所示，第1期应付的本金为1610.35，利息为16000，两者之和为17610.35元。其值与PMT函数计算的每期等额还款额是一样的。

21.2.5 CUMPRINC( )、CUMIPMT( )函数

CUMPRINC函数用于返回一笔贷款在给定的 start_period 到 end_period 期间累计偿还的本金数额。

CUMIPMT函数用于返回一笔贷款在给定的 start_period 到 end_period 期间累计偿还的利息数额。

语法：CUMPRINC(rate, nper, pv, start_period, end_period, type)

语法：CUMIPMT(rate, nper, pv, start_period, end_period, type)

参数说明：

rate：利率

nper：总付款期数。

pv：现值

start_period：计算中的第一个周期。付款期数从1开始计数。

end_period: 计算中的最后一个周期。

type：付款类型，数字0或1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

如图 21‑10所示，某人向金融机构贷款2 400 000元，贷款期限为30年，年利率为8%，计算月还款的第1次至第12次中的累积本金和累积利息分别是多少？

在B8、B9单元格中输入以下公式，可分别计算月还款的第1次至第12次中的累积本金和累积利息额。

=CUMPRINC(B1/12,B2*12,B3,B4,B5,B6)

=CUMIPMT(B1/12,B2*12,B3,B4,B5,B6)

图 21-10 计算两个付款期之间累积支付的本金和利息

21.2.7 EFFECT( ) NOMINAL( )函数

EFFECT函数用于计算在给定的名义利率和每年的复利期数下的实际年利率。

语法：EFFECT(nominal_rate, npery)

参数说明：

nominal_rate：名义利率。

npery：每年的复利期数。

如图 21‑11所示，在 B3中输入以下公式，可以将名义利率为5%，复利计算期数为12转成实际年利率。

=EFFECT(B1,B2)

图 21-11 名义年利率转实际年利率

NOMINAL函数用于计算在给定的实际利率和每年的复利期数下的名义年利率。

语法：NOMINAL(effect_rate, npery)

NOMINAL函数语法具有下列参数：

effect_rate：实际利率。

npery：每年的复利期数。

如图 21‑12所示，在 B3中输入以下公式，可以将实际年利率为5%，复利计算期数为12转成名义年利率。

=NOMINAL(B1,B2)

图 21-12 实际年利率转换成名义年利率

21.2.7 RATE( )函数

RATE用于计算年金的各期利率。

语法：RATE(nper, pmt, pv, [fv], [type], [guess])

参数说明：

nper：年金的付款总期数。

pmt: 每期的固定付款金额。

pv: 现值。

fv：未来值，如果省略 fv，则假定其值为 0。

type：付款类型，数字0或1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

guess：预期利率，它是一个百分比值，省略该参数时默认值为10%。

如图 21‑13所示，某人向金额机构贷款36000元，贷款期限为4年，每月固定还款额为1500元。在B4单元格中输入以下公式，可计算该笔年金的年利率。

=RATE(B1*12,B2,B3)

图 21-13 计算年金利率

在B2单元格中每月还款额用负数表示，表示现金的流出，若用户在工作表中用正数表示每月还款额，可在RATE公式中的第二个参数前加上负号，即公式书写为 =RATE(B1*12,-B2,B3)。其他财务函数中类似负号问题，均可采用此方法处理。

21.2.8 NPER( )函数

NPER函数用于基于固定利率及等额分期付款方式下，计算某项投资或贷款的期数。

语法：NPER(rate,pmt,pv,[fv],[type])

参数说明：

rate:各期利率。

pmt: 各期所应支付的固定金额。

pv:现值。

fv:未来值，或在最后一次付款后希望得到的现金余额。 如果省略 fv，则假定其值为 0。

type：付款类型，数字 0 或 1，用以指定各期的付款时间是在期初还是期末，0或省略表示支付时间为每期期末，1表示每期期初。

如图 21‑14所示，某人向金融机构购买理财产品，该理财产品年报酬率为4%，每月固定投资额为250元，每期初投资，该用户初始投资额为2000，现需要计算该用户需要投资多少期（月）可实现20000元的未来值。

在B7单元格可输入以下公式，可计算投资期数（月）。

=NPER(B1/12,B2,B3,B4,B5)

图 21-14 计算投资期数

图 21-15 计算达到投资值所需的月数

21.2.9 FVSCHEDULE( )函数

FVSCHEDULE函数返回应用一系列复利率计算后的初始本金的终值。

语法：FVSCHEDULE(principal, schedule)

参数说明：

principal:现值。

schedule:利率数组

如图 21‑16所示，本金为20000，未来三个年度的利率分别为4%、5%、6%，在B6单元格中输入以下公式，可以计算出在不同利率下的初始本金的终值。

=FVSCHEDULE(B1,B2:B4)

图 21-16 计算不同利率下的终值

21.2.10 NPV( )函数

NPV函数用于使用贴现率和一系列未来支出（负值）和收益（正值）来计算一项投资的净现值。

语法：NPV(rate,value1,[value2],...)

参数说明：

rate：某一期间的贴现率。

value1, value2, ...：value1 是必需的，后续值是可选的。这些是代表支出及收入的1到254 个参数。NPV 使用 value1, value2,... 的顺序来说明现金流的顺序。一定要按正确的顺序输入支出值和收益值,并且这些值在时间上必须具有相等的间隔。

如图 21‑17所示，某企业投资一项理财产品，其现金流出与流入为B3:B6区域，贴现率为4%。在B8单元格中输入以下公式，可计算该项投资的净现值。

=NPV(B1,B4:B6)+B3

图 21-17 计算净现值

21.2.11 XNPV( )函数

XNPV函数返回一组现金流的净现值，这些现金流不一定定期发生。若要计算一组定期现金流的净现值，请使用函数 NPV。

语法：XNPV(rate, values, dates)

参数说明：

rate:应用于现金流的贴现率。

values:与 dates 中的支付时间相对应的一系列现金流。

dates:与现金流支付相对应的支付日期。

如图 21‑18所示，区域B3:B10为现金流量，A3:A10为现金流发生日期，单元格B1为贴现率，在B11单元格输入以下公式，可计算这些系列的现金流的净现值。

=XNPV(B1,B3:B10,A3:A10)

图 21-18 计算不定期的现金流的净现值

21.2.12 IRR( )函数

IRR函数用于计算一系列现金流的内部收益率。

语法：IRR(values, [guess])

参数说明：

values：投资期间的现金流。IRR 使用值的顺序来说明现金流的顺序。必须保证支出值和收益值以正确顺序输入。

guess：对函数 IRR 计算结果的估计值。Excel 使用迭代法计算IRR函数。 从 guess 开始，IRR 不断修正计算结果，直至其精度小于 0.00001%。多数情况下，不必为 IRR 计算提供 guess 值。如果省略 guess，则假定它为 0.1 (10%)。

如图 21‑19所示，在B8单元格中输入以下公式，可计算B1:B6区域中现金流的内部收益率。

=IRR(B1:B6)

图 21-19 计算定期内部收益率

21.2.13 XIRR( )函数

XIRR函数返回一组不一定定期发生的现金流的内部收益率。若要计算一组定期现金流的内部收益率，请使用IRR函数。

语法：XIRR(values, dates, [guess])

参数说明：

values：与dates 中的支付时间相对应的一系列现金流。

dates：与现金流支付相对应的支付日期。

guess : 对函数 XIRR 计算结果的估计值。

如图 21‑20所示，区域B2:B7为现金流量，A2:A7为现金流发生日期,在B8单元格中输入以下公式，可计算这些不定期现金流的内部收益率。

=XIRR(B2:B7,A2:A7)

图 21-20 计算不定期现金流的内部收益率